System Requirements

Browser

Requirement

Details

Supported Browsers

Google Chrome (recommended), Edge, Mozilla Firefox

Not Supported

Internet Explorer, Safari

Minimum RAM

12 GB

Required Technology

WebGL enabled

Recommended: Google Chrome offers the best performance due to its faster Chromium V8 engine. Our default test environment is Chrome.

Useful Links:

OpenBrIM Launcher

Chrome throttles background tabs to save resources, which can significantly slow down analysis and result extraction when minimized.

The OpenBrIM Launcher configures Chrome for optimal performance:

Feature

Benefit

Background analysis

Runs at full speed when minimized

Result extraction

~50% speed when minimized (vs. near-zero without)

Isolated profile

Keeps OpenBrIM sessions separate from regular browsing

Download: Copy the script below and save it as OpenBrIM-Launcher.bat:

@echo off
setlocal enabledelayedexpansion
title OpenBrIM Launcher

set "CONFIG=%USERPROFILE%\.openbrim_config"

if exist "%CONFIG%" (
    set /p COMPANY=<"%CONFIG%"
    echo.
    echo Using saved company: !COMPANY!
    echo Opening https://!COMPANY!.openbrim.org
    echo.
    set /p "CHOICE=Press Enter to continue or type 'change' to update: "
    if /i "!CHOICE!"=="change" goto :ask
    goto :launch
)

:ask
echo.
echo Your OpenBrIM URL looks like: https://yourcompany.openbrim.org
set /p "INPUT=Enter your company name only (e.g., wsp, kiewit, atkins, jacobs): "

if "!INPUT!"=="" (
    echo No company name entered. Exiting.
    pause
    exit /b
)

:: Remove https:// if present
set "COMPANY=!INPUT:https://=!"
:: Remove http:// if present
set "COMPANY=!COMPANY:http://=!"
:: Remove .openbrim.org if present
set "COMPANY=!COMPANY:.openbrim.org=!"
:: Remove trailing slash if present
set "COMPANY=!COMPANY:/=!"

echo !COMPANY!>"%CONFIG%"
echo Company name saved: !COMPANY!

:launch
start "" "C:\Program Files\Google\Chrome\Application\chrome.exe" ^
    --disable-background-timer-throttling ^
    --disable-renderer-backgrounding ^
    --disable-background-tab-freezing ^
    --disable-backgrounding-occluded-windows ^
    --disable-hang-monitor ^
    --disable-ipc-flooding-protection ^
    --disable-gpu-vsync ^
    --disable-features=CalculateNativeWinOcclusion,TabFreeze,TabGroupsCollapseFreezing,BackForwardCache,BackgroundMediaSuspend,IntensiveWakeUpThrottling ^
    --user-data-dir="C:\ChromeProfiles\OpenBrIMSession" ^
    --profile-directory=Default ^
    --new-window "https://!COMPANY!.openbrim.org/"

Note: The script assumes Chrome is installed at C:\Program Files\Google\Chrome\Application\chrome.exe. If Chrome is installed elsewhere, update the path in the script. To find your Chrome path, type chrome://version in Chrome's address bar and look for "Executable Path".

No installation or admin privileges required. On first run, enter your company name (e.g., companyname for companyname.openbrim.org). The launcher saves your preference for future use.

Enhancing Platform Performance

Laptops and browsers often conserve battery by limiting hardware utilization. Adjust these settings for optimal performance.

Use Discrete GPU

Step 1: Check which GPU Chrome is using. Open chrome://gpu/ and find "GL Renderer".

Step 2: Open NVIDIA Control Panel (search "Nvidia" in Windows). Select Chrome or Edge and assign "High Performance Nvidia Processor".

Step 3 (Alternative): Search "Graphics Settings" in Windows, select "Desktop App", browse to your browser's .exe file, click "Options", and set your preferred GPU.